Dragon Age: The Veilguard Launcher

Playing Veilguard through the cancer that is the EA Launcher?

Same, bro. Same.

If you’re tired of EA’s obnoxious post-session storefront spam, the below script should solve your problems. It fires up the game, then when finished, kills the launcher so you only get a blipvert of spam at best. Drop this script in Veilguard’s folder, name it something distinctive (“Launch_DragonAge.bat” would work), and then use this to start the game.

You’ll need to check and/or change a few things based on your install:

• The EA App installed itself in a subdirectory of itself on my system. No, I don’t know why – I suspect because EA are dicks (the cause of this post, after all). If you’re launcher is not in “C:\Program Files\Electronic Arts\EA Desktop\EA Desktop\EADesktop.exe,” change that line to the right location.
• You can tune up or down the first timeout based on system performance. This usually works at 7 for me, but sometimes EA will be extra obnoxious in loading their spam as the launcher fires up which stymies this, so I’ve had to leave it around 11 for flawless execution.
• Update your game’s executable location if it’s not “E:\Games\Dragon Age The Veilguard\Dragon Age The Veilguard.exe” – I believe in you.

Seriously, fuck whichever cretinous suit who thought spamming a customer with a storefront riddled with sports games was the next best action they should force on a player.

@echo off

echo Step 1: Checking if EA Desktop is running...
REM Ensure EA Desktop is running
tasklist /NH /FI "IMAGENAME eq EADesktop.exe" 2>nul | find /I "EADesktop.exe" >nul
if %ERRORLEVEL% neq 0 (
    echo EA Desktop not running. Starting EA Desktop...
    start "" "C:\Program Files\Electronic Arts\EA Desktop\EA Desktop\EADesktop.exe"
    REM set 10 higher or lower depending on your system performance; EA Desktop needs to fully load or it borks loading DATV
    timeout /t 11 /nobreak >nul
) else (
    echo EA Desktop is already running.
)

echo Step 2: Launching Dragon Age launcher...
REM Use start /wait to hold the batch script until the launcher completes its process
start /wait "" "E:\Games\Dragon Age The Veilguard\Dragon Age The Veilguard.exe"

echo Step 3: Waiting for Dragon Age game process to start...
:check_game_running
timeout /t 1 /nobreak >nul

REM Debug output for tasklist check
echo Checking if game process "Dragon Age The Veilguard." is running...

REM Check if the game process is running with tasklist, exact name
tasklist /FI "IMAGENAME eq Dragon*" 2>nul | find /I "Dragon Age The Veilguard." >nul
if %ERRORLEVEL% neq 0 (
    echo Game process not found, retrying...
    goto check_game_running
)

echo Dragon Age game detected. Monitoring game process...

REM Loop to wait until the game process exits
:monitor_game
timeout /t 5 /nobreak >nul
echo Checking if game process "Dragon Age The Veilguard." is still running...

tasklist /FI "IMAGENAME eq Dragon*" 2>nul | find /I "Dragon Age The Veilguard." >nul
if %ERRORLEVEL%==0 goto monitor_game

echo Game exited. Waiting before killing EA Desktop...
timeout /t 5 /nobreak >nul

echo Step 4: Killing EA Desktop process...
REM Kill EA Desktop
taskkill /f /im "EADesktop.exe"
echo EA Desktop closed.

exit